import dev.deftu.gradle.utils.*

import dev.deftu.gradle.tools.minecraft.CurseRelation
import dev.deftu.gradle.tools.minecraft.CurseRelationType
import com.modrinth.minotaur.dependencies.DependencyType
import com.modrinth.minotaur.dependencies.ModDependency

plugins {
    java

    id("dev.deftu.gradle.multiversion")
    id("dev.deftu.gradle.tools")
    id("dev.deftu.gradle.tools.resources")
    id("dev.deftu.gradle.tools.minecraft.api")
    id("dev.deftu.gradle.tools.minecraft.loom")
    id("dev.deftu.gradle.tools.publishing.maven")
    id("dev.deftu.gradle.tools.minecraft.releases")
}

repositories {
    maven("https://api.modrinth.com/maven")
}

dependencies {
    if (mcData.isFabric) {
        modImplementation("net.fabricmc.fabric-api:fabric-api:${mcData.dependencies.fabric.fabricApiVersion}")
        modImplementation(mcData.dependencies.fabric.modMenuDependency)
    }
}

loom {
    accessWidenerPath = file("../../src/main/resources/cc.accesswidener")
}

java {
    base.archivesName.set(modData.id)

    tasks {
        if (isLoomPresent()) {
            named<org.gradle.jvm.tasks.Jar>("remapJar") {
                archiveBaseName.set(modData.id)
            }
        } else {
            named<Jar>("jar") {
                archiveBaseName.set(modData.id)
            }
        }
    }
}

/*
minecraft {
    accessTransformer = file("../../src/main/resources/META-INF/accesstransformer.cfg")
}
*/

toolkitReleases {
    detectVersionType.set(true)

    rootProject.file("changelogs/${modData.version}.md").let { file ->
      if (file.exists())
        changelogFile.set(file)
    }

    modrinth {
        projectId.set("Fs6mB0ic")

        if (mcData.loader == ModLoader.FABRIC) {
            dependencies.addAll(listOf(
                ModDependency("P7dR8mSH", DependencyType.REQUIRED), // Fabric API
                ModDependency("mOgUt4GM", DependencyType.OPTIONAL)  // Mod Menu
            ))
        }
    }

    curseforge {
        projectId.set("901062")

        if (mcData.loader == ModLoader.FABRIC) {
            relations.addAll(listOf(
                CurseRelation("fabric-api", CurseRelationType.REQUIRED), // Fabric API
                CurseRelation("modmenu",    CurseRelationType.OPTIONAL)  // Mod Menu
            ))
        }
    }
}